irrlicht/wds
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity
Files
c326c363a0bf0d218106625c5b5e835b8fd40f6f
wds/assets/interactions/cinema.ink
T
irrlicht 7543fe3cb7 Cinema Inkscript
2026-06-15 10:39:25 +02:00

1114 lines
53 KiB
Plaintext
Raw Blame History

This file contains ambiguous Unicode characters
This file contains Unicode characters that might be confused with other characters. If you think that this is intentional, you can safely ignore this warning. Use the Escape button to reveal them.
// Cinema 24/7
// Schauplatz: Das Kino — Lobby → Foyer → Labyrinth-Etagen → Theater 4 → Nails
//
// Variablen:
// favor_nails — Nails' Stimmung; > 0 = Sympathie, < 0 = Genervtheit
// past_it — Spieler ist an Theater 4 vorbeigegangen (bool)
// fallbear — temporär: Bär verliert Gleichgewicht beim Ausweichen
//
// Stub-Knoten (noch zu schreiben):
// the_show, cbear, shadow_battle, apprentice, quitter,
// her_portfolio, performance, practice, seeulater
VAR favor_nails = 0
VAR past_it = false
VAR fallbear = false
VAR boop_success = false
VAR snaks = 0
VAR had_sweets = 0
-> the_cinema
== the_cinema ==
The lobby has a very retro, synth-wave, neon, 70s look to it. The carpet alone makes your eyes hurt. This is not a cheeky metaphor for its ugliness. Your eyes really hurt when you stare at it for any length of time because the shades of blue and red, mixed together on it in geometric patterns, are so bright they make your vision dance in the low light. At a glance, something in the part of your brain that is responsible for processing visual data seems to short-circuit and you see the patterns move against each other, impossibly on the static floor.
* [>>>]
-
Better look to the ceiling with its wavey cutouts backlit by colorful LED.
The ticket booth is unmanned of cause, as is the snack dispensary. Which seems well stocked at least. The popcorn even looks fresh. Well, it smells fresh at least. The scent of pleasantly burned sugar is heavy in the air.
The ribbon barrier is closed but easy enough to bypass. Is it closed? It looks open. Though abandoned. But not for long. Not the abandonment of disrepair, only the monetary abandonment place like this experience between beginning and end of the shows. When all the visitors sit in their seats and the staff takes this moment to slip away for a quick smoke break. Something like that. Full behind doors but empty in the open.
* [>>>]
-
You can even hear sounds that must be a film playing. Screams and gunfire. You hope someone left the door to that particular theatre open and that is why you can hear it so clearly. Because if the sound insulation is that shit, the movie going experience can´t be very good here.
* [Slip under the ticket barrier]
You raise the ribbon of the barrier and duck under it. Almost without a thought.
-> the_foliar
* [Go to the ticket booth]
The graspable of the ticket booth is plastered with advertisements, movie posters and prohibition signs informing visitors of behaviours and attire within the cinema. The slip you took for a "closed" sign that hangs in the middle of the glass says the following.
"No tickets required. Precede with caution."
On the little table where someone would place their tickets, there is another slip reading:
"Warning:
Everyone is free to enter.
But it is advised only to visit the auditoriums where no film is currently being played.
As the films are a bit extreme for most audiences.
Thank you for your visit!"
** [Go into the cinema]
You can open the flimsy barrier from here. It is secured right next to where you stand. So you enter the foliar.
-> the_foliar
** [Leave the cinema] You leave.
-> END
-> the_foliar
== the_foliar ==
The foliar is big. With couches to wait and meet and lounge on. The room is only broken up by advertising columns. Some of them display movie posters, though most are empty.
A long bar stretches the length of the back wall. Behind it chips and candy are stacked on shelves like thoughs of an actual bar. It even has a mirrored backwall, which visually multiplies the colourful packaging. This pattern is only broken by enormous popcorn machines, which are full to the brim.
Do you want to grab a snack?
* [Of cause]
~ snaks = 1
** [Sweet] You grab a sweet snack. You are lucky. They have your favourite.
~ had_sweets = 1
** [Salty] You grab a salty snack. You are lucky. They have your favourite.
* [I don't think so] You better not risk it.
-
To both sides of the room are stairs. This is a multi-floor cinema.
-> groundfloor
== groundfloor ==
+ [Go to the right staircase]
{not (f1 > 0 or f2 > 0):
You choose the right staircase to ascend to the first floor.
Pictures of actors in film scenes decorate the walls. They are probably supposed to be famous. Iconically recognisable. You know none of them. However, some catch your eye as familiar until you take a second look. They are certainly not cheap generic-property knockoffs to avoid copyright infringement. It's just a coincidence.
A big number: 1 marks the landing to the next floor.
}
{f1 > 0 or f2 > 0:
You enter the first floor.
}
-> f1.r
+ [Go to the left staircase]
{not (f1 > 0 or f2 > 0):
You choose the left staircase to ascend.
Pictures of actors in film scenes decorate the walls. They are probably supposed to be famous. Iconically recognisable. You know now of them. However, some catch your eye as familiar until you take a second look. They are certainly not cheap generic-property knockoffs to avoid copyright infringement. It's just a coincidence.
A big number: 2 marks the landing to the next floor.
}
{f1 > 0 or f2 > 0:
You enter the second floor.
}
-> f2.l
// ── Etagen-Labyrinth ────────────────────────────────────────────────────────
// Die Stockwerk-Verbindungen sind absichtlich nicht-euklidisch.
// Treppenauf/-ab führen nicht zu linear benachbarten Etagen.
== f1 ==
= r
+ [Go down the corridor.] -> f1.l
+ [Take the stairs up.]
You enter the fifth floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f5.r
+ [Take the stairs down.]
You enter the sixth floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f6.r
= l
+ [Go down the corridor.] -> f1.r
+ [Take the stairs up.]
You enter the third floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f3.l
+ [Take the stairs down.]
You enter the seventh floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f7.l
== f2 ==
= r
+ [Go down the corridor.] -> f2.l
+ [Take the stairs up.]
You enter the sixth floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f6.r
+ [Take the stairs down.]
You enter the seventh floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f7.r
= l
+ [Go down the corridor.] -> f2.r
+ [Take the stairs up.]
You enter the fifth floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f5.l
+ [Take the stairs down.]
You enter the first floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f1.l
== f3 ==
= r
+ [Go down the corridor.] -> f3.l
+ [Take the stairs up.]
You are back on the ground floor.
-> groundfloor
+ [Take the stairs down.]
You enter the second floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f2.r
= l
+ [Go down the corridor.] -> f3.r
+ [Take the stairs up.]
You enter the sixth floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f6.l
+ [Take the stairs down.]
You enter the seventh floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f7.l
== f4 ==
= r
+ [Go down the corridor.]
{not past_it:
You go down the corridor. It is empty. Some of the doors are closed. Some are slightly open. When you get close to the door of theatre 4 you can hear soft sounds. There is no film playing in the theatre according to the sign beside the door.
- else:
The corridor is still the same. And there are still the same faint noises coming out of theatre 4.
}
** [Enter] So you enter. -> f4r4
** [Go past it.]
~ past_it = true
You go past it.
You walk closer to one wall. You want to run your fingers along it while you walk, but can´t quite bring yourself to do so. To move the final millimetre closer to the wall. As if you are on tracks. Soon you are at the other side of the floor.
-> f4.l
+ [Take the stairs up.]
You enter the fifth floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f5.l
+ [Take the stairs down.]
You are back on the ground floor.
-> groundfloor
= l
+ [Go down the corridor.]
{not past_it:
You go down the corridor. It is empty. Some of the doors are closed. Some are slightly open. When you get close to the door of theatre 4 you can hear soft sounds. There is no film playing in the theatre according to the sign beside the door.
- else:
The corridor is still the same. And there are still the same faint noises coming out of theatre 4.
}
** [Enter] So you enter. -> f4r4
** [Go past it.]
~ past_it = true
You go past it.
You walk closer to one wall. You want to run your fingers along it while you walk, but can´t quite bring yourself to do so. To move the final millimetre closer to the wall. As if you are on tracks. Soon you are at the other side of the floor.
-> f4.r
+ [Take the stairs up.]
You enter the seventh floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f7.l
+ [Take the stairs down.]
You are back on the ground floor.
-> groundfloor
== f5 ==
= r
+ [Go down the corridor.] -> f5.l
+ [Take the stairs up.]
You enter the second floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f2.r
+ [Take the stairs down.]
You enter the third floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f3.l
= l
+ [Go down the corridor.] -> f5.r
+ [Take the stairs up.]
You enter the first floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f1.l
+ [Take the stairs down.]
You enter the sixth floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f6.l
== f6 ==
= r
+ [Go down the corridor.] -> f6.l
+ [Take the stairs up.]
You enter the first floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f1.r
+ [Take the stairs down.]
You enter the fourth floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.}}
-> f4.r
= l
+ [Go down the corridor.] -> f6.r
+ [Take the stairs up.]
You are back on the ground floor.
-> groundfloor
+ [Take the stairs down.]
You enter the third floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f3.l
== f7 ==
= r
+ [Go down the corridor.] -> f7.l
+ [Take the stairs up.]
You enter the third floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f3.r
+ [Take the stairs down.]
You enter the fifth floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f5.r
= l
+ [Go down the corridor.] -> f7.r
+ [Take the stairs up.]
You enter the fourth floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.}}
-> f4.l
+ [Take the stairs down.]
You enter the second floor. {~It looks like all the others.|||{~It looks the same as all the others.|More hallway. More carpet.|Just another floor}}
-> f2.l
// ── Theater 4 ───────────────────────────────────────────────────────────────
== f4r4 ==
You push the door open to a few steps bringing you the level where the seats are. The theatre screen is lit in a faint pink that floods the dingy room with a pleasant atmosphere. The seats lie in shadow, but they look empty.
+ [Go to the screen] -> f4r4.to_the_screen
+ [Sit down in the closest seat] -> f4r4.frontrow_to_show
+ [Go to the back] -> f4r4.backseat
= to_the_screen
You go through the aisle to the very front. You are so close to the screen here that your entire field of view is absorbed by this shade of pink, if you angle your head right.
+ [Go closer to the screen so your shadow falls on it]
You take a few more steps until your silhouette emerges as a dark shape from the dark lower border of the screen.
++ [Raise your arms] You raise your arms to see your shadow do the same.
++ [Walk to the side] You walk a few steps to the side to see your shadow do the same.
--
Until the enormous shape of a wolf jumps at you from the side. You only see it come for a second before you flinch away.
But there is no impact, it is just another shadow. It looked very real out of the corner of your eye. On a second look, you see that it is the projection of masterfully interwoven fingers, cast from the back of the theatre.
-> f4r4.first_duet
+ [Turn back to the seats]
But you turn away from it and to the seats again. From here you have a better view of the theatre and can see a shape, sitting in the elevated rows on the back half of the room.
-
A voice comes from there.
Her: OMG! I totally don't believe it? Is that an audience? OK. OK. OK, sit down. The show is about to start.
++ [Take a seat]
You sit down in the front row and look up to the screen.
-> f4r4.the_show
++ [Go to the person]
You are more curious about this person than the show. So you decide to make your way up the dark rows of seats to get a better look.
-> f4r4.the_performer
= frontrow_to_show
You slump down in the closest seat. You are fairly far to the front. So you can lie your head down on the back of the seat to look up into the abyss of pink.
You have huffed out only one deep breath before the shadow of a giant hand rips the light and colour of the screen apart.
+ [I´m startled]
You startle at that and turn around in your seat to look for the source of the shadow.
Against the glare of the projector you can just about make out two hands which are raised over the rows of seats.
You raise a hand against the bright light. But before your eyes can adjust to the dark, you hear a voice.
Her: Eyes front, please. Or you´ll miss the show.
The voice has the twang of mock annoyance.
++ [Turn to the screen] You comply and look to the screen again. -> f4r4.the_show
++ [Go to investigate] You get up and go towards the back, where the figure is. -> f4r4.the_performer
--
+ [This is fine.]
++ [I turn to look for the shadow maker]
You turn around in your seat to look for the source of the shadow.
Against the glare of the projector you can just about make out two hands which are raised over the landscape of cushioned backrests.
You raise a hand against the bright light. But before your eyes can adjust to the dark, you hear a voice.
Her: Eyes front, please. Or you´ll miss the show.
The voice has the twang of mock annoyance.
+++ [Turn to the screen] You comply and look to the screen again. -> f4r4.the_show
+++ [Go to investigate] You get up and go towards the back, where the figure is. -> f4r4.the_performer
---
++ [I keep looking at the screen]
You keep your eyes on the screen unperturbed and follow the movements of the shadows with your eyes.
-> f4r4.silent_show
= backseat
When you are at the cinema, do you always prefer the seats at the very back? You make your way there now, automatically. You shimmy into the aisles and pick a seat. You sit down. It is comfortable. It is fine. You relax, with the whole room in view.
-> f4r4.the_show
= the_performer
Her: No. It´s fine. You can sit down in the front as well. Just there will be fine.
+ [Continue to the back]
~ favor_nails = favor_nails - 1
You continue your way despite her protests.
Her: Just sit down! Urgh. Now I have to delay the performance.
You have reached the row where the figure sits and huffs unhappily at you. You can still only see their outline in the dark. Something about it is strange. Their head is oddly big. It has a weird shape, too.
Her: Fine, you can sit in the back row if you have to. No respect for the craft.
+ [Take a seat where you are] She sounds annoyed. You decide to obey and sit down in the middle row. -> f4r4.the_show
- (just_sit_damnit)
* [Who are you?]
You: Who are you?
Her: Only the greatest visual artist you will ever meet. Not that you would be able to appreciate it, since you refuse to sit down for the performance to start.
++ [That's not really an answer.]
~ favor_nails = favor_nails - 3
You: That's not really an answer.
Her: Oh mahhai, unbelievable. Don't be such a pain in the ass just sit down or get out of my theatre.
+++ [What kind of performance?]
~ favor_nails = favor_nails - 1
You: What kind of performance?
Her: Are you for fudging real? Just sit down and find out?
-> just_sit_damnit
+++ [Can I sit with you?]
Her: I need some space to perform. Just keep a little bit of a distance.
++++ [Sit down across the aisle] You just sit down in the first seat across the aisle from her. -> f4r4.the_show
++++ [Take a seat two places away from her]
You shimmy into the aisle where she is and sit down with a double seat of space to her. A side glance in her direction subjects ruffely knit fabrics and jangling bracelets.
-> f4r4.the_show
++++ [Sit down in the back row]
You´d actually prefer to sit in the back row. So you go and take your seat, your back against the wall, with the whole theatre in view.
-> f4r4.the_show
+++ [You just sit your ass down across the aisle from her]
You just sit down in the first seat across the aisle from her.
-> f4r4.the_show
+++ [Sit down in the back row]
You prefer to sit in the back row. So you go and take your seat, your back against the wall, with the whole theatre in view.
-> f4r4.the_show
--
* [Can I sit with you?]
~ favor_nails = favor_nails + 1
You: Can I sit with you?
Her: Oh. Well, actually I need a bit of space to perform. But you can sit here if you want.
You can just make out a hand with long, pink acrylic nails and glittering rings gesturing to a place two seats away from her.
You shimmy into the aisle and take the seat. A side glance in her direction subjects ruffely knit fabrics and jangling bracelets.
-> f4r4.the_show
* [Sit down across the aisle from her]
You sit down in the first seat across the aisle from her.
-> f4r4.the_show
* [Sit down in the back row]
You prefer to sit in the back row. So you go and take your seat, your back against the wall, with the whole theatre in view.
-> f4r4.the_show
= first_duet
* [Try to see the one making the shadow]
You turn, raising your hand against the light of the projector. But too late, the glare has already gotten into your eyes and you can´t make out anything in the darkness of the room.
An amused voice comes out of the darkness.
Her: Watch out, here it comes again.
++ [Turn to the screen]
Turn back towards the screen and see the wolf pace your shadow. Readying itself for the next attack.
-> f4r4.first_duet
++ [Go investigate]
You start up the aisle between the seats.
A voice comes out of the darkness.
Her: Whahat? Don´t tell me you didn´t like that. That was A-Class theatre. You know I don't get an audience here often. Take a seat and I´ll show you a real show.
-> f4r4.the_performer
* (bunny)[Make the shadow figure of a bunny, to run from the wolf]
You position your hands to make the figure of a bunny.
++ It´s ears wiggle nervously. [] The ears of the wolf twitch in turn, with anticipation.
++ It rubs its nose with its front paws in an attempt to be too cute to be eaten. [] But there is only a low hungry growl from the back of the theatre.
--
Your bunny decides to make a run for it.
The wolf jumps after it with graceful movements. It is quick and deadly.
++ [The bunny flees off screen]
Your bunny flees to the side of the screen and jumps into the unlit void. Trusting that nonexistence will keep it safe from the jaws of the predator.
-> f4r4.quitter
++ [The bunny flees across the screen]
Your bunny hops across the screen. You have to be fast and clever and change directions often to get away from the monster chasing you.
--
Soon you are short of breath and turn once more to see the wolf mid air just above you. Maw wide, ready to consume you. The running is over. You only have a second to decide what to do.
++ [Accept your fate]
So you accept your fate and cower the bunny down in a final primal reflex, before the wolf is on top of you and swallows you whole.
You are blacked out by the shape of it for a moment and can see the hands raised above the seats silhouetted against the rays of beamer light. Maybe it is just the perspective or something but they seem gigantic.
Then the shadow of the wolf moves beside you again. The light punches you in the face and it wags its tail. A voice comes from the back of the room.
Her: Ahhh! That was SOOOOO FUN. More. More. More.
+++ [I think I need to catch my breath first.]
You: I think I need to catch my breath first.
Her: Hm. Okie doke. You wanna see one of my specialities?
++++ [Sure.] You: Sure.
You take your front row seat and look up to the screen.
-> f4r4.the_show
++++ [Who are you?]
You: Who are you?
Her: I´m the baddest bitch alive. Now sit your ass down and let me put on a show.
----
-> f4r4.the_show
++++ [Sit] You indulge her and sit. -> f4r4.the_show
++++ [Go up to her] You make your way up the aisles to her. -> f4r4.the_performer
+++ [OK. But next time I won´t be such easy prey.]
You: OK. But next time I won´t be such easy prey.
Her: Uh. You want a shadow battle? Bring it oooooon.
-> f4r4.shadow_battle
---
++ (cheat)[Turn into a crocodile]
So you dissolve the bunny to spread your arms wide. Creating the long jaws of a crocodile. It is a desperate move and unexpected enough that the wolf can´t stop before plunging dead first into the trap you just created. You snap your arms together.
The wolf´s whine becomes a whiny voice.
Her: NOOOOOOO. That's not fair. Not fair. Not fair.
+++ [Says who?]
You: Says who?
Her: Says ME! You can´t just change the rules like that.
You: I wasn´t aware there were any rules.
Her: But I wanted to eat you!
++++ [You can eat my ass.]
She laughs.
Her: EW! I don't even know you.
+++++ [We can change that.]
~ favor_nails = favor_nails + 1
You: We can change that.
Her: WOW. You coming on strong. I can´t even tell if you´re cute from up here. We will have to meet somewhere where it is light, some time.
++++++ [It´s a date.] You: It´s a date.
She giggles.
------
Her: I wanna practice some more of my figures. Do you wanna watch?
-> f4r4.practice
++++++ [How about now?] You: How about now?
------
Her: I wanna practice some more of my figures. Do you wanna watch?
-> f4r4.practice
+++++ [I don´t know you either.]
You: I don´t know you either.
Her: You know my work. So you already know I´m fab as fuck.
++++++ [True.] You: True.
Her: Do you wanna see some more?
+++++++ [Sure.] You: Sure. -> f4r4.the_show
+++++++ [I would actually like to get to know you.]
You: I would actually like to get to know you.
Her: HHHM. I actually wanna practice some more figures. But we can grab snacks after.
++++++++ [Can I watch you practice?]
You: Can I watch you practice?
Her: Sure.
-> f4r4.practice
++++++++ [Should I come back later to pick you up?]
You: Should I come back later to pick you up?
Her: If you want.
--------
You: OK, I will see you in a bit.
-> f4r4.seeulater
-------
Her: Nice. What do you want to see? My portfolio or a Full Performance?
+++++++ [Portfolio] You: Your portfolio? Now I´m curious. -> f4r4.her_portfolio
+++++++ [Performance] You: I would like to see a performance. -> f4r4.performance
-----
++++ [No don't eat me. I can get you popcorn instead.]
Her: NAWWW! OK. Fair is fair.
+++ [Sorry.]
You: Sorry. But I don't want to die today.
Her: Well, you shouldn't have been a bunny then, gorgeous. A wolf has to eat.
* [Make the shadow figure of a bear, to confront the wolf]
You make a bear...
Do you know how to make a bear shadow figure?
++ [YES]
OK. You make a bear. But due to your position relative to the screen it is too tiny to confront the wolf.
++ [NO] You don't make a bear. -> f4r4.first_duet
--
The wolf is watching you impatiently.
++ [Make the bear bigger] You decide to make a bigger bear.
++ [Do something else] -> f4r4.first_duet
--
But the beast on the screen beside you has clearly had enough and is readying its next attack.
++ [Make your way to the back of the room]
You can´t compete from down here. So you start to make your way up the aisles to some high ground.
As soon as you step out of the light of the screen a voice comes from the back.
Her: No! Where are you going? I thought we were going to play?
You squint up and into the dark and see two abnormally large hands raised over the seats and backlit by the projector.
+++ [I´m just coming up to project better.]
You: I´m just coming up to project better.
Her: I think you´ll need a little more than that to get on my level.
++++ [I´m sure.] You: I´m sure.
Her: You can still show me what you've got, though. Come here.
-> f4r4.deathmatch
++++ [We will see.] You: We will see.
Her: OK. A challenge? IT. IS. ON.
-> f4r4.deathmatch
+++ [Who are you?]
You: Who are you?
Her: Ähm, Hellooho? I´m just the greatest show master in this place. Maybe in the world. Your pleasure.
++++ [How was I supposed to know that?]
~ favor_nails = favor_nails - 1
Her: OK I forgive you, that you have no taste. I´ll even put on a show, yes? Sit down.
+++++ [Sit] You sit in the seat nearest to you. -> f4r4.the_show
+++++ [Go up to her] You continue to go up to her. -> f4r4.the_performer
+++++ [I thought we were going to make a wolf and bear death match?]
You: I thought we were going to make a wolf and bear death match?
Her: Ya. OK. You can come here so I can obliterate you.
-> f4r4.deathmatch
++++ [I think they have failed to put up a poster for you downstairs.]
Her: What do you expect? There is no fudging respect for real art in this place. So lame. Sit down and I´m gonna give you the real off the hook showy show stuff.
+++++ [Sit] You sit in the seat nearest to you. -> f4r4.the_show
+++++ [Go up to her] You continue to go up to her. -> f4r4.the_performer
+++++ [I thought we were going to make a wolf and bear death match?]
You: I thought we were going to make a wolf and bear death match?
Her: Ya. OK. Come here and bring it on then.
-> f4r4.deathmatch
++ [Run to the back of the room]
You are just a tiny thing down here, without a fighting chance. You bolt up the aisle to get yourself some size.
There is a startled squeak from the back of the room.
+++ [Ignore it]
You charge on. To a spot where you will be big enough. You jump on to a seat for more high ground and make a much better sized bear.
-> f4r4.bear
+++ [Look up]
You look up and slow down. Squinting into the darkness you can see a figure in one of the raised rows. Your opponent.
You arrive at a spot where you will be big enough. You jump on to a seat for more high ground and make a much better sized bear.
-> f4r4.bear
++ [Clamber over the seats like a crazy person]
You are just a tiny thing down here, begging to be eaten alive. You jump and clamber over the backs of the seats to get yourself some size.
There is laughter from the back of the theatre.
Her: HAHAHA what are you doing? The wolf is not actually gonna eat you, you know?
+++ [Continue] You don't stop. Only slow down a little to look up.
+++ [Halt] You stop to look up.
---
You can see two giant backlit hands. Forming a wolf.
+++ [Best to be sure it won´t eat me.]
Her: Jup. OK?
You have made enough ground and are standing up on a seat now. You make a bear that is much better sized.
You: Jup. Much better. Thanks. Let´s GO.
-> f4r4.bear
+++ [I was just trying to get some high ground for a counterattack.]
Her: Oh! You think you can challenge me? Bring it on.
You have made enough ground and are standing up on a seat now. You make a bear that is much better sized.
You: Let´s go.
-> f4r4.bear
* [Mime your bloody death from the wolf attack]
Your reaction time is a bit off. But it is not too late yet to mime your bloody murder by the claws of the beast. You put some theatricality into your death scene.
Your reward is amused laughter from the back of the theatre as the wolf dissolves into hands.
++ [Take a bow]
You take a theatrical bow. Which is rewarded with some fluttery applause.
++ [Try to see the shadow maker]
You raise your hand and squint against the beamer's glare to see your attacker. You can only just about see two very large hands.
--
Her: Do another one. Do another one!
++ [Ok. Attack me again.] You: Ok. Attack me again. -> f4r4.unicorn
++ [Make your own shadow puppet]
You decide to try your own hand at shadow puppeteering.
Do you even know how to do that?
+++ [Yes]
Alright. You make a...
++++ [Wolf] A small wolf.
++++ (bunny_puppet)[Bunny] A bunny.
++++ [Butterfly] A butterfly.
++++ [Spider] A scuttling spider.
----
Her: Sorry. Not sorry. I´m not impressed. But it is also veeeerrrrryyyy hard to impress me.
+++ [No]
You don't really know how but you can still make a shadow figure with your full body.
So you make...
++++ [A worm] A worm, by raising your hand over your head and making a wave with your whole body.
++++ (kitty)[Yourself cat ears]
Your hands into cat ears. They turn and twitch.
+++++ [Miou.]
~ favor_nails = favor_nails + 1
You: Miou.
Her: Naw
++++ [Yourself antlers] Your hands into majestic antlers protruding from your head.
++++ [A T-pose] A T-pose. You had other ideas, but I guess you like being trash.
Her: Hmmm. OK? What are you supposed to be?
----
---
Her: I possibly see the tiniest bit of talent here. Maybe if you work at it we could make a show together. If you try to upstage me you are out, though.
-> f4r4.apprentice
* [Try to replicate the wolf]
You try to figure out how exactly the shape of the wolf is made and to interlock your own fingers to replicate the effect.
++ [Observe] You observe...
--
++ [Build the finger form] Arrange the fingers...
--
++ [Project]
// TODO: per Shuffle zufällig zwischen "passable" und "ugly" wechseln.
// Inklecate unterstützt keine mehrzeiligen {~}-Sequenzen — braucht
// VAR wolf_ugly + { shuffle: - ... - ... }-Syntax oder zwei Pfade.
And... you create a passable attempt. Much smaller and a little crooked, maybe.
--
= unicorn
Her: OK. OK. Do this one.
The hands resolve themselves into the shape of a unicorn.
+ [Try to pacify the beast]
You hold out your hand in an attempt to pacify the beast.
The unicorn huffs and scuffs a hoof against the floor.
++ [Shhh. Easy. It´s fine.]
The unicorn doesn't seem convinced. It shakes its head in irritation.
+++ {snaks} [Present the snacks you picked up as a peace offering]
You: Here I have something for you.
You hold out the sweets you picked up earlier.
Her: OMG! You have snacks? I want some. I want some! Get up here!
She sounds so excited, you have to oblige.
-> f4r4.snacksharing
+++ [Persist in being soothing]
You still persist in making soothing noises and hold your hands up.
But it doesn't help.
+++ [Prepare for an attack]
You step back a little and square your stance for the next attack.
---
++ [Prepare for an attack]
You step back a little and square your stance for the next attack.
--
+ [Prepare for the attack]
You square your stance in anticipation for the next attack.
-
It scuffs its hoofs, rears up and charges you.
+ [Dodge]
In the last moment you perform a jump-roll to the side.
Her: Hey! You can't dodge-roll in two dimensions!
++ [Worth a try!]
You: Worth a try!
Now you are in the position of squaring off with the unicorn again. It charges once more.
+++ [Dodge]
You dodge-roll again and hear a frustrated shout from the back of the theatre.
As you get back up again you see the shadow unicorn is already on top of you. Trampling you to death instead.
Her: There serves you right you jumping Jack. Are you trying to steal my scene? You know for a moment there I thought this was kind of fun. Tell me: what are your acting references?
++++ [Get impaled]
---
---
++ [Oh Yeah? Watch me!]
You: OH Yeah? Watch me!
You proceed to dodge-roll across the stage like a hedgehog on speed.
Between rolls you see the bewildered unicorn watch you from the side.
+++ [You could probably surprise it and boop it on the nose]
~ boop_success = RANDOM(0, 1) == 1
{boop_success:
You jump-roll towards it, get up and manage a quick boop on its nose before dodge-rolling away again.
- else:
You jump-roll towards it. But unfortunately it wasn't that distracted and before you can boop it, it has lowered its horn and is making you into crazy-person-shashlik.
}
{not boop_success: -> after_boop}
++++[Celebrate your victory]
You stop to raise your hands up into the air to celebrate your victory. Meanwhile there is sarcastic clapping from the backseats.
Her: wow. OK. Great show, I guess. Very... acrobatic
---- (after_boop)
+++ [Continue rolling]
You can´t stop now. So you dodge-roll until you become nauseous and you are out of breath.
You just collapse on the floor and take some deep breaths. It's getting warm in the beamer light.
On the screen beside you, you can see the shadow unicorn come up to you cautiously and sniff you.
++++ [Raise a hand]
You raise a hand to show up on the screen. The unicorn raises its head out of reach again.
Her: OH Good. You are not dead.
++++ [Sit up]
You sit up and the unicorn steps back from your shadow. Satisfied you are ok.
Her: Oh Good. You are not dead.
----
---
++ [Just wanted to make it a bit more interesting.]
You: Just wanted to make it a bit more interesting.
Her: Convince me of your acting talent first. We can work-shop it once I have decided you are worth it to share a stage with me.
The unicorn charges again.
+++ [Dodge]
You dodge-roll again.
Her: HEY!
As you get back up again you see the shadow unicorn is already on top of you. Trampling you to death.
Her: There serves you right you jumping Jack. Are you trying to steal my scene? Tell me: what are your acting references?
++++ [Get impaled]
---
--
You try even harder for your second death scene. Now that you know you have an appreciative scene partner and audience. You cheat to the side of the screen to see the unicorn and its movement. It has got you through the solarplexus and you convulse with the jerks of its head. When it finally pulls its horn up and out, you go with the movement and fall face first to the floor. You just about manage to make it a stage fall and not knock your teeth out on the thin scratchy carpet.
You stay on the floor until you hear clapping.
Her: I have to say, that wasn´t bad. I mean I clearly carried the scene. But it really makes the action more lively with an acting partner. Tell me: what are your references?
* [I did some acting in school.] You: I did some acting in school.
Her: Wouldn't go boasting with that.
* [I actually have a degree in acting.] You: I actually have a degree in acting.
Her: Well, there is no such thing as a legitimate art adjudication, you know.
* [I am just a natural.] You: I am just a natural.
Her: Ha. Sure thing sweety. Don't talk about a natural, when I´m at the table.
-
Her: I can accept this as a first audition, I think. I know I´m hard to impress. The competition is very absent, though. But I think I really saw a bit of style in there. Deep, deep down. Maybe I can make a passable partner of you. Yas. I totally see the vision.
-> f4r4.snacksharing
= snacksharing
You go up the aisle towards the dark silhouette. It is too dark to make much out. When you are a few rows away you see the form move. You see arms and shoulders and above them something which is not the shape of a head.
When you are at her row, she is just stepping out onto the aisle. Her high heeled shoes make no sound on the carpet. She straightens her frilly dress and puts one of the straps that slipped off her shoulder back in its rightful place.
When you look up to her face, your eyes adjust enough for you to see. A mess of long fingers unfurls itself into the clear shape of two gigantic but delicate hands, bedecked in rings and acrylic nails, growing from a slender neck with a y2K choker.
+ [I think she is cool.]
She is very cool indeed.
You hold out the snacks.
Her: Yummy. Oh maaaan it´s been tooooo long.
She grabs the package from your hand.
Her: I don't know. I guess I´ve just been so focused on perfecting my performance lately. I guess I haven't really had any time to get out. And walking up and down all the stairs. Urgh. Hate that.
One of her hands faces to the front and forms a snout with three fingers to the front while the Pinky and index finger perk up. Her makeshift foxface looks down to the package of snacks.
{had_sweets:
Her: MMHHhhh Yum! Sweets. I always need something sweet.
She tears at the plastic wrapping and tosses a piece up into her hand which folds into a fist briefly. A second later, when her hand resumes the foxface the piece of candy is gone.
Her: Hm. OK. Ordinary candy.
She studies the package again.
Her: Didn't even know they had those here. Sweet. But that's it. You should try some of the local sorts. They pack a little more ZING.
- else:
Her: Hugh. Salty snacks. OK I guess. Sorry, I normally prefer sweets. But I'd still like to try some.
She tears at the plastic wrapping and tosses a piece up into her hand which folds into a fist briefly. A second later, when her hand resumes the foxface the snack is gone.
Her: Hm? Is it just a normal snack?
She studies the package again.
Her: Didn't even know they had those here. You should try some of the local stuff. It's a little more interesting.
}
+ [I think she is scary.]
You are a little intimidated.
Her: What? Don't worry, I don't bite. Well, Nah you've seen the worst of my bite down there during the show.
One of her hands faces to the front and forms a snout with three fingers to the front while the Pinky and index finger perk up. She opens and closes the fingers a little as she talks. It looks like someone comically ventriloquising a hand puppet. It doesn't look genuine.
Her: Or maybe I will bite if you keep these sweets you promised me.
You raise your hand with the package and she snatches it from you. Her makeshift foxface looks down at the bag of snacks.
{had_sweets:
Her: MMHHhhh Yum! Sweets. I always need something sweet.
She tears at the plastic wrapping and tosses a piece up into her hand which folds into a fist briefly. A second later, when her hand resumes the foxface the piece of candy is gone.
Her: Hm. OK. Ordinary candy.
She studies the package again.
Her: Didn't even know they had those here. Sweet. But that's it. You should try some of the local sorts. They pack a little more ZING.
- else:
Her: Hugh. Salty snacks. OK I guess. I normally prefer sweets. But I guess this is a total emergency situation.
She tears at the plastic wrapping and tosses a piece up into her hand which folds into a fist briefly. A second later, when her hand resumes the foxface the snack is gone.
Her: Hm? Is it just a normal snack?
She studies the package again.
Her: Didn't even know they had those here. You should try some of the local stuff. It's a little more interesting.
}
-
-> END
= deathmatch
Her: If you are a grizzly bear, then I will be a dragon.
You: Then I will be the winter wind. Blowing out your flame and freezing you.
Her: Then I will be the ocean. Then you could never blow away.
You: My wind will be waves then. Sitting on top of you. Disturbing your depths.
Her: I will be the moon then. So you will have to bow to my every will.
+ [Flirt... yes please]
~ favor_nails = favor_nails + 1
+ [I will be the earth so you can only be as bright as I want you to be.]
-
Her: Then I am the sun. So only I can decide where the light is.
The screen blacks out except for a small globe of light.
-> END
= bear
The wolf is snarling and fierce as before, but its tail twitches a little. You have intimidated it, by the looks of it.
Your bear is on its hind legs and looming tall.
You must never underestimate how dangerous a desperate animal is.
+ [Check your stance.]
You are standing a bit unsafely on the chairs. So, you take your eyes off your opponent for a second to check your stance.
As you shift your right foot into a safer position the projector light on your cheek is disturbed. You can see out of the corner of your eye how the shadow grazes you. As you snap your attention up to the screen you see the wolf on your bear's hump. Biting down savagely.
You don't even have to think about it, as you raise your paws and beat at the side of the wolf. The force of it is enough to send it flying off of you and skidding to the edge of the screen. It is up on its feet again in seconds.
++ [Roar at it.]
Your bear is not very hurt but furious. You send out a roar. A warning and a threat.
But the wolf will not back down. It charges again.
++ [Run to it to attack.]
You have no time to lose either, so you jump from the seat. The bear gallops towards the wolf.
--
++ [Bite] The bear is quick on four feet and opens its massive jaws to welcome the wolf.
++ [Thrash] The bear stands tall and swipes a paw at the beast.
--
The wolf has left itself enough of an opening to jump back in time.
++ [Bite] You bite. But it jumps over you.
++ [Thrash] You thrash. But it jumps around you.
--
You try a few more attacks. But the wolf is careful and nimble now.
It is baiting you. Cunning. You can already start to feel the strength of your attacks receding.
+ [Start your first attack]
You are ready.
++ [Swipe a paw at the wolf]
As the wolf jumps toward you the bear stands tall and swipes a massive paw down.
The wolf is quick but not quick enough to escape the attack completely. You catch it across its back and its jowls as it jumps away again.
++ [Bite at the wolf.]
The wolf jumps forward and the bear comes down to all four legs to bite at it.
The wolf is quick and jumps back from the bear's teeth, which scrape its back but don't manage the catch. A pained howling is your only reward.
--
The wolf paces for a moment.
++ [Wait] You wait to see its next move.
Then it jumps forward again, jaws snapping.
+++ [Bite] The bear snaps its jaws right back. But the wolf has left itself enough of an opening to jump back in time.
+++ [Thrash] But the bear is ready and strikes. The wolf has left itself enough of an opening to jump back in time.
+++ [Dodge]
~ fallbear = RANDOM(0, 1) == 1
{fallbear:
You only have to take a step back to be out of reach. But it only takes a step to destabilise you. And you fall.
- else:
It is slower so, the bear can just step back out of reach.
}
{not fallbear: -> after_dodge_inner}
You can mostly brake your fall by catching the seats. You hang awkwardly in the row.
++++ [Admit defeat]
You: Well played.
Her: Are you giving up?
You: What can I say. You got me.
You disentangle yourself from the seats. The wolf meanwhile resolves itself into a set of triumphant hands.
Her: Haha. Yes I did. But don't be embarrassed, I can tell you! You totally never stood a chance. I am the master of the craft. You wanna see some of my other specialities?
+++++ [Yes] You: Yes -> f4r4.her_portfolio
++++ [Get back up]
You quickly disentangle yourself from your compromised position. The wolf is already sniffing interestedly at the spot where you disappeared. Hungry for its kill.
++++ [Turn into a crocodile to ambush it]
It is right above you now. An easy kill for an ambush predator. Your arms become the strong, crushing maw of a crocodile in a second. Jumping up as if from the watering hole. Swallowing the front half of the wolf in one bite. There isn't even enough time for it to scream in pain. You have become a swift and merciless death.
You slide back to the depths. Drawing the carcass of the wolf along.
Her: That was sooooooo not fair!
She sounds a little out of breath.
You: Well nature isn't fair.
Her: You shape shifted. That has nothing to do with nature.
You: It's called a plot twist.
Her: Ya a bad one. And what even happened to the bear? This isn't very narratively satisfying.
You: I'm sure the crocodile is satisfied.
Her: Oh my god. Just because you wanted to win. This makes no sense whatsoever!? If you could be bothered to stick to a storyline I would have destroyed you.
+++++ [OK. I'm sorry.]
Her: Ya u better be. Now sit your ass down and I'm gonna show you how it's done.
-> f4r4.the_show
+++++ [You might have. If you were more flexible.]
Her: Ah!? What did you just say? You can accuse me of many things but this is just slander! How dare you.
-----
---- (after_dodge_inner)
---
++ [Attack]
But yours will be the next move.
+++ [Bite] The bear comes forward to snap its jaws. But the wolf has left itself enough of an opening to jump back in time.
+++ [Thrash] The bear is ready and strikes. The wolf has left itself enough of an opening to jump back in time.
---
--
You try a few more attacks. But the wolf is careful and nimble now.
++ [Bite] You bite. But it jumps over you.
++ [Thrash] You thrash. But it jumps around you.
--
It is baiting you. Cunning. You can already start to feel the strength of your attacks receding.
= cbear
// TODO: Gegenangriff-Bär — Bär greift aus erhöhter Position an
-> END
= the_show
// TODO: Die eigentliche Vorstellung — Nails' Schattentheater
// Übergang in silent_show (stilles Beobachten) oder interaktiv
-> silent_show
= silent_show
A second shadowy hand joined the first. They wrap around each other and devolve into a mass of darkness with pins of light, shining between the bends of fingers which you no longer can tell apart or identify.
The splotch bulges and warps. Forming shapes you almost recognise. Organic shapes. No symmetry or clean edges.
Does your brain try to identify and categorise the shapes?
Do you see the pattern formed by projector light in the middle? Is it the fur pattern of an imaginary animal?
Do you see landscapes or stars?
The profiles of faces you know but can't place crown the edges of the shadow. There and gone in a moment.
Are you trying to figure out if the curtains are blue? There are no curtains. And if there were it would be rude to figure out the colour. Don't be distracted. Focus on the show. Someone is performing for you here.
The ink on the screen devolves itself into a shape your brain can grasp easily now. It is a Swan. Swimming on the water. It is perfect. Wings folded. The body smooth as a pebble. The neck long and arcing, bending up and around and down.
It dips its head into the water, gracefully. Kissing the ripples of the surface demurely before pulling back and shaking off water.
-> END
= shadow_battle
// TODO: Schattenkampf — Nails' wolf vs. Spieler's bear, freie Wahl
-> END
= apprentice
// TODO: Nails nimmt Spieler als Lehrling an
-> END
= quitter
// TODO: Hase flüchtet vom Bildschirm — feige Niederlage
-> END
= her_portfolio
// TODO: Nails zeigt ihr Shadow-Portfolio
-> END
= performance
// TODO: Nails' volle Vorstellung
-> END
= practice
// TODO: Nails übt neue Figuren, Spieler schaut zu
-> END
= seeulater
// TODO: Verabredung für später — Spieler kommt nochmal
-> END
Reference in New Issue View Git Blame Copy Permalink